model{

for (i in 1:n){

    logit(pi[i]) <-beta1[case[i]]*(alpha[justice[i]]-beta2[case[i]])
    pi.adj[i]<-e1+(1-e1-e2)*pi[i]
    y[i]~dbern(pi.adj[i])   
   # y.rep[i]~dbern(pi[i])
}

e1 ~ dunif(0, .1)
e2 ~ dunif(0, .1)

for(j in 1:n.justices){
    alpha[j] ~ dnorm(mu.alpha.hat[j],T.alpha)
    mu.alpha.hat[j] <-  mu.alpha + gamma.party*party[j]

        z.alpha[j] <- (alpha[j] - ref.mean)/ref.sd
}
            T.alpha <- pow(sigma.alpha,-2)
            sigma.alpha ~ dunif(0,1000)
            z.sigma.alpha <- sigma.alpha / ref.sd
            mu.alpha ~ dnorm(0,.0001)

 for(c in 1:n.cases){
    beta1[c] ~ dnorm(mu.beta1, T.beta1)
    beta2[c] ~ dnorm(mu.beta2, T.beta2)
        z.beta2[c] <- (beta2[c] - ref.mean)/ref.sd
        z.beta1[c] <- beta1[c] * ref.sd 
}
            mu.beta1 ~ dnorm(0,.0001)
            z.mu.beta1 <- mu.beta1*ref.sd
            T.beta1 <-  pow(sigma.beta1,-2)
            sigma.beta1 ~ dunif(0,1000)
            z.sigma.beta1 <- sigma.beta1 * ref.sd 

            mu.beta2 ~ dnorm(0,.0001)
            z.mu.beta2 <- (mu.beta2 - ref.mean)/ref.sd
            T.beta2 <-  pow(sigma.beta2,-2)
            sigma.beta2 ~ dunif(0,1000)
            z.sigma.beta2 <- sigma.beta2 / ref.sd

    gamma.party ~ dunif(0, 1000)
        z.gamma.party <- gamma.party/ref.sd 
            

ref.mean <- mean(alpha[])
ref.sd <- sd(alpha[])

}
#do y.reps in R--see appendix C
#histogram of gamma.party to show constraint
